Commander X16

Code: Select all

; calculate how far an object has fallen:  d = 1/2 * g * t^2.
; we set g = 9.81 m/sec^2, time = 5 sec -> d = 122.625 m.

CHROUT = $ffd2
FOUT   = $fe06
FMULTT = $fe21
FDIV   = $fe24
CONUPK = $fe5a
MOVFM  = $fe63

    lda  #4
    sta  $01         ; rom bank 4 (BASIC) contains the fp routines.
    lda  #<flt_two
    ldy  #>flt_two
    jsr  MOVFM
    lda  #<flt_g
    ldy  #>flt_g
    jsr  FDIV        ; FACC= g/2
    lda  #<flt_time
    ldy  #>flt_time
    jsr  CONUPK      ; ARG = time
    jsr  FMULTT      ; FACC = g/2 * time
    lda  #<flt_time
    ldy  #>flt_time
    jsr  CONUPK      ; again ARG = time
    jsr  FMULTT      ; FACC = g/2 * time * time
    jsr  FOUT        ; to string
    ; print string in AY
    sta  $02
    sty  $03
    ldy  #0
loop:
    lda  ($02),y
    beq  done
    jsr  CHROUT
    iny
    bne  loop
done:
    rts

flt_g:      .byte  $84, $1c, $f5, $c2, $8f  ; float 9.81
flt_time:   .byte  $83, $20, $00, $00, $00  ; float 5.0
flt_two:    .byte  $82, $00, $00, $00, $00  ; float 2.0

Code: Select all

def from_c64_float(num):
    excess_exp = (num >> 32)
    if excess_exp == 0:
        return 0.0
    exp = (excess_exp-0x80)-32
    sign = 1 if num & 0x80000000 == 0 else -1
    man= 0x80000000 + (num & 0x7fffffff)
    return float(sign * (2**exp) * man)

def to_c64_float(num):
    if num == 0:
        return 0
    sign = 0x80000000 if num < 0 else 0
    num_abs = abs(num)
    exp = math.floor(math.log(num,2))
    if 0 > (exp + 0x81) or (exp + 0x81) > 255:
        raise FloatingPointError(f"exponent {exp+0x81} is not in the range 0..255")
    man = round(num_abs * 2 ** (31 - exp)) & 0x7fffffff
    return(((exp + 0x81)<<32) + (sign) + man)